Chip 1998 February/CHIP Şubat 1998.iso/drivers/SESK/somaria/INSTALL.DAT

Text File | 1994-05-13 | 48KB | 1,481 lines

 /*----------------------------------------------------------------------
 *      FILE:
 *              install.dat
 *
 *      DESCRIPTION:
 *
 *      Install.dat is an installation script for copying Aria DOS
 *      utilities, Aria Windows utilities, and the Aria Windows
 *      driver to hard disk.  It also allows the user to run a sound card test
 *      program and set up the Windows driver.  If Windows is not loaded,
 *      the Aria Windows driver cannot be set; and a warning box is
 *      displayed.
 *
 *-------------------------------------------------------------------
 */


@DefineProject
    @Name           = "Aria Sound Card"
    @Version        = "PS1-1.1"
    @OutDrive       = C
    @Subdir         = "\\ARIA"
    @Group          = "Z"
    @Immediate      = 1
@EndProject

@DefineVars
//
// set all configuration variables
//
    @Qstring @ArPort = "290"
    @Qstring @ArIRQ = "10"
    @Qstring @ArDMA = "5"
    @Qstring @SBPort = "220"
    @Qstring @SBIRQ = "7"
    @Qstring @SBDMA = "1"
    @Qstring @MiPort = "330"
    @Qstring @MiIRQ = "9"
    @QString @SiPort = "NONE"
    @QString @SiIRQ = "NONE"
    @Qstring @AdPort = "388"
    @Qstring @JoyPort = "200"  // Default setting is disabled
    @QString @JoyPort2 = "NORMAL"
    @QString @JoySpeed = "NORMAL"
    @Qstring @AriaConf = "T1"
    @QString @OldSiPort = "310"


//
//      Variables to store the sets of available settings returned by QAINFO
//
    @QString @ArIOSet = ""
    @QString @ArIRQSet = ""
    @QString @ArDMASet = ""
    @QString @SBIOSet = ""
    @QString @SBIRQSet = ""
    @QString @SBDMASet = ""
    @QString @MiIOSet = ""
    @QString @MiIRQSet = ""
    @QString @SiIOSet = ""
    @QString @AdIOSet = ""
    @QString @JoyIOSet  = ""
    @QString @JoySpeedSet = "NORMAL,FAST"

    @Integer @Parameter = 99
    @QString @SetStr  = "XXX"
    @QString @Setting1 = ""
    @QString @Setting2 = ""
    @QString @Setting3 = ""
    @QString @Setting4 = ""
    @QString @Setting5 = ""
//
// decimal values of port adresses
//
    @Integer @ArPortHex
    @Integer @SBPortHex
    @Integer @MiPortHex
//
// variables for Windows driver set up
//
    @QString @dspport = " "
    @QString @Rsize = "R1"
    @QString @WinDir = "C:\\WINDOWS"
    @Integer @Flag1 = 0
    @Integer @Flag2 = 0
//
// variables to hold paramater values returned by diagnostic utility
//
    @QString @ParamSet = ""
    @QString @TempStr = ""
    @Integer @ModifyMode = 0
    @QString @AriaDir = @StrHead(@ScriptFile,@Strlen(@Scriptfile) - 12)
@EndVars
@FlushOptions()

@If(@Spawn("BIN\\winchk.exe") == 1)   // confirm not running from within Windows DOS shell
   @Display
             RUN CONFIGURATION PROGRAM FROM DOS





   You should run the Aria configuration program from DOS, not from
   within a Windows DOS shell. Exit Windows, change to the Aria home
   directory on your hard drive, and type "config".

   @PauseX
   @EndDisplay
   @Exit
@EndIf

@If(!@Exists("@StartupDrive:@StartupDir\\BIN\\qainfo.exe"))
   @AriaDir = @StrHead(@ScriptFile,@StrFind(@ScriptFile,"INSTALL.DAT") - 1 )
   @ChangeDir(@AriaDir)
@Else
   @AriaDir = "@StartupDrive:@StartupDir"
@Endif

@If (@Exists("aria.cfg"))
  @OldSiPort = @ReadLine("aria.cfg",8,"=")
@EndIf

@FlushGroups()
@SetGroup(C)

@If (@Spawn("BIN\\findaria.com") > 0)        // disable board to prevent a conflicting configuration from hanging INSTALL
  @Spawn("BIN\\boardcfg /Se 0 disable.cfg")
@EndIf

MainMenu:
CUSTOM_MENU:
@If (C [= @Group)
   @If(!@Exists("cfg.001")) @SetGroup(U) @SetGroup(F) @EndIf  // first-time custom installation; prompt to set up Windows driver
   @GetOption                                                 // after modifying AUTOEXEC.BAT
   @ClearOption(2)
   @ClearOption(3)
   @ClearOption(5)
   @LocalWindow(14,37)
   @Cls
            ARIA SOUND CARD CONFIGURATION



   Select "Change hardware settings" to modify your current sound card setup.

   Select "Set up Aria Windows driver" if you have removed the Aria driver
   from your Microsoft Windows configuration.


   @Option 2 = "Change hardware settings"
   @Option 3 = "Set up Aria Windows driver"
   @Option 5 = "Exit to DOS"

   @EndOption
   @If (5 [= @Option)
     @If(!@Exists("aria.cfg"))


       @Display
            RE-BOOT YOUR COMPUTER



     The configuration program automatically disables your sound card after
     you type "config".  If you are exiting this program without setting up
     your hardware, you must re-boot your PC to enable the sound card.  You
     should also re-boot if you change your sound card's hardware settings
     (I/O, IRQ, or DMA).

     To re-boot your computer, turn the power off and on.
          @PauseX
       @EndDisplay
     @Else
    @Spawn("BIN\\boardcfg /Se 0 aria.cfg")
     @EndIf
     @Exit
   @ElseIf (2 [= @Option)
       @If(@Exists("cfg.001"))
         @ModifyMode = 1
       @EndIf
       @GoTo HARDWARE_SETUP
   @ElseIf(3 [= @Option)
       @SetGroup(W)
       @Spawn("BIN\\boardcfg /Se 0 aria.cfg")
       @GoTo SetupWin
   @EndIf
@EndIf // END CUSTOM_MENU


QAINFO:
// ***** Prompt to run QAINFO.EXE, the PC diagnostic utility that scans
// ***** the computer for available resources.  Giving the user the user the
// ***** option not to run QAINFO allows for manual setup in the event QAINFO
// ***** does not operate properly on a particular computer.

HARDWARE_SETUP:

QuickQAINFO:
   @FlushOptions()
@If (Q [= @Group)
   @ModifyMode = 0
   @SetOption(1)
   @GoTO QUICK_DIAGNOSTIC
@EndIf

   @GetOption
   @FlushKeyboard
   @ClearOption(1)
   @ClearOption(2)
   @ClearOption(3)
   @LocalWindow(18,37)
   @Cls
                 PC DIAGNOSTIC UTILITY

     Your sound board communicates with your computer through a variety of
     system resources: input/output (I/O) ports, interrupts (IRQs), and
     Direct Memory Access (DMA) channels.  To operate properly, your sound
     board must use resources that are not allocated to other devices.

     This program includes a PC diagnostic utility that scans your computer
     for available resources.  The diagnostic utility identifies those board
     settings that should not conflict with other devices in your system.

     If you have had difficulty running the diagnostic utility in the past,
     do not run the utility.

   @Option 1 = "Run the diagnostic utility"
   @Option 2 = "Do not run the diagnostic utility"
   @Option 3 = "Return to previous menu"

@EndOption

QUICK_DIAGNOSTIC:
@If (3 [= @Option)
   @If (C [= @Group)
      @GoTo CUSTOM_MENU
   @Else
      @GoTo MainMenu
   @EndIf
@ElseIf (1 [= @Option)      // ***** confirm that board is disabled
               // ***** QAINFO PROMPT OPTIONS

  @SetOption(666)
  @If (@Spawn("BIN\\findaria.com") > 0)
     @Spawn("BIN\\boardcfg /Se 0 disable.cfg") //disable card
  @EndIf
   @Display
   @LocalWindow(17,38)
   @Cls
                 EXECUTING DIAGNOSTIC

     Your sound board communicates with your computer in a variety of ways:
     input/output (I/O) ports, interrupts (IRQs), and Direct Memory Access
     (DMA) channels.  To operate properly, your sound board must use computer
     resources that are not used by other devices.  This program includes a
     PC diagnostic utility that is scanning your computer for available
     resources.  Scanning should take less than 15 seconds.

     If you experience any problems while running the diagnostic utility,
     type "config" from the ARIA home directory on your hard drive.  Select
     "Change hardware settings", choose "Do not run the diagnostic utility",
     and complete the hardware setup.  Remember to set up the Aria Windows
     driver with any changed settings.
   @If (@spawn("BIN\\qainfo -t204 -t205 -fout") == -1) QAINFO not found or needs more memory to run!! @EndIf
   @If (@Spawn("BIN\\readlog 4") == -1) READLOG not found!! @EndIf @Pause
@EndDisplay


// ***** load available parameter info from QAINFO logfile

   @ArIOSet  =  @ReadLine("logfile.txt",0,"=")
   @ArIRQSet =  @ReadLine("logfile.txt",1,"=")
   @ArDMASet =  @ReadLine("logfile.txt",2,"=")
   @SBIOSet  =  @ReadLine("logfile.txt",3,"=")
   @SBIRQSet =  @ReadLine("logfile.txt",4,"=")
   @SBDMASet =  @ReadLine("logfile.txt",5,"=")
   @MiIOSet  =  @ReadLine("logfile.txt",6,"=")
   @MiIRQSet =  @ReadLine("logfile.txt",7,"=")
   @SiIOSet  =  @ReadLine("logfile.txt",8,"=")
   @AdIOSet  =  @ReadLine("logfile.txt",9,"=")
   @JoyIOSet =  @ReadLine("logfile.txt",10,"=")

   @Delete("OUT")
   @Delete("logfile.txt")

@ElseIf (2 [= @Option)
  // ***** user chose not to run QAINFO; assign all possible parameters to
  // ***** set variables


   @ArIOSet  =  "290,280,2A0,2B0,NONE"
   @ArIRQSet =  "10,11,12,NONE"
   @ArDMASet =  "5,6,NONE"
   @SBIOSet  =  "220,240,NONE"
   @SBIRQSet =  "7,5,9,NONE"
   @SBDMASet =  "1,0,NONE"
   @MiIOSet  =  "330,320,NONE"
   @MiIRQSet =  "9,5,7,NONE"
   @SiIOSet  =  "300,310,320,330,NONE"
   @AdIOSet  =  "388,NONE"
   @JoyIOSet =  "200,NONE"

@EndIf  // ***** QAINFO PROMPT OPTIONS

// ***** configure board with suggested settings

@If (@ModifyMode == 0)
// Set Aria parameters to first available setting in respective parameter sets
// value will be either a valid value or "NONE"

      @ArPort = @NextAvailSetting(@ArIOSet,"20")
      @ArIRQ  = @NextAvailSetting(@ArIRQSet,"20")
      @ArDMA  = @NextAvailSetting(@ArDMASet,"20")
      @SBPort = @NextAvailSetting(@SBIOSet,"20")
      @SBIRQ  = @NextAvailSetting(@SBIRQSet,"5")
      @If(!(@StrToInt(@SBIRQ) == 7))
     @SBIRQ = @NextAvailSetting(@SBIRQSet,"20")
      @EndIf
      @SBDMA  = @NextAvailSetting(@SBDMASet,"20")
      @MiPort = @NextAvailSetting(@MiIOSet,"20")
      @MiIRQ  = @NextAvailSetting(@MiIRQSet,@SBIRQ)
      @SiPort = @NextAvailSetting(@SiIOSet,@MiPort)
      @AdPort  = @NextAvailSetting(@AdIOSet,"20")
//      @JoyPort = @NextAvailSetting(@JoyIOSet,"20")    Default setting is disabled



@Else  // ***** User will be modifying settings in current configuration
       // ***** retrieve current configuration

     @ArPort = @ReadLine("aria.cfg",0,"=")
     @ArIRQ  = @ReadLine("aria.cfg",1,"=")
     @ArDMA  = @ReadLine("aria.cfg",2,"=")
     @SBPort = @ReadLine("aria.cfg",3,"=")
     @SBIRQ  = @ReadLine("aria.cfg",4,"=")
     @SBDMA  = @ReadLine("aria.cfg",5,"=")
     @MiPort = @ReadLine("aria.cfg",6,"=")
     @MiIRQ  = @ReadLine("aria.cfg",7,"=")
     @SIPort = @ReadLine("aria.cfg",8,"=")
     @AdPort = @ReadLine("aria.cfg",10,"=")
     @JoyPort = @ReadLine("aria.cfg",11,"=")
     @JoySpeed = @ReadLine("aria.cfg",12,"=")

     @If (666 [= @Option)
    @ClearOption(666)
    @TempStr = "@ArPort*"
    @If (@StrFind(@ArIOSet, @TempStr) > -1)
       @SetOption(301)
    @EndIf
    @TempStr = "@ArIRQ*"
    @If (@StrFind(@ArIRQSet, @TempStr) > -1)
       @SetOption(302)
    @EndIf
    @TempStr = "@ArDMA*"
    @If (@Strfind(@ArDMASet, @TempStr) > -1)
       @SetOption(303)
    @EndIf
    @TempStr = "@SBPort*"
    @If (@Strfind(@SBIOSet, @TempStr) > -1)
       @SetOption(304)
    @EndIf
    @TempStr = "@SBIRQ*"
    @If (@Strfind(@SBIRQSet, @TempStr) > -1)
       @SetOption(305)
    @EndIf
    @TempStr = "@SBDMA*"
    @If (@Strfind(@SBDMASet, @TempStr) > -1)
       @SetOption(306)
    @EndIf
    @TempStr = "@MiPort*"
    @If (@Strfind(@MiIOSet, @TempStr) > -1)
       @SetOption(307)
    @EndIf
    @TempStr = "@MiIRQ*"
    @If (@Strfind(@MiIRQSet, @TempStr) > -1)
       @SetOption(308)
    @EndIf
    @TempStr = "@SiPort*"
    @If (@Strfind(@SiIOSet, @TempStr) > -1)
       @SetOption(309)
    @EndIf


    @TempStr = "@AdPort*"
    @If (@Strfind(@AdIOSet, @TempStr) > -1)
       @SetOption(311)
    @EndIf
    @TempStr = "@JoyPort*"
    @If (@Strfind(@JoyIOSet, @TempStr) > -1)
       @SetOption(312)
    @EndIf
    @EndIf
@EndIf



@If(@StrFind(@JoyIOSet,"200*") > -1)
   @JoyIOSet = "NORMAL*,FAST*,NONE"
@Else
   @JoyIOSet = "NORMAL,FAST,NONE"
@EndIf

@If (Q [= @Group)
      @If(@StrIndex(@JoyPort,2) == 'N')
     @JoyPort2 = "NONE"
      @Else
     @If(@StrIndex(@JoySpeed,2) == 'R')
        @JoyPort2 = "NORMAL"
     @ElseIf(@StrIndex(@JoySpeed,2) == 'S')
        @JoyPort2 = "FAST"
     @ElseIf(1)
        @JoyPort2 = "NORMAL"
     @EndIf
      @EndIf

   @GoTo VERIFY_PARAMETERS
@EndIf
@JoySpeedSet = "NORMAL,FAST"

@ChDir("BIN")

@Flag1 = 0
ModifyParameters:

@If (@StrToInt(@ArPort) == -1)
     @ClearOption(301)
     @ArIRQ = "NONE"
     @ClearOption(302)
     @ArDMA = "NONE"
     @ClearOption(303)
     @SBPort = "NONE"
     @ClearOption(304)
     @SBIRQ = "NONE"
     @ClearOption(305)
     @SBDMA = "NONE"
     @ClearOption(306)
     @MiPort = "NONE"
     @ClearOption(307)
     @MiIRQ = "NONE"
     @ClearOption(308)
     @SiPort = "NONE"
     @ClearOption(309)
     @AdPort = "NONE"
     @ClearOption(311)
     @JoyPort = "NONE"
     @JoyPort2 = "NONE"
     @ClearOPtion(312)
     @SetCursor(2)
     @SetOption(300)  // flag ModifyParameter screen to display proper text
@Else
      @ClearOption(401)
      @ClearOption(402)
      @ClearOption(300)
      @If(@StrToInt(@ArIRQ) == -1)
     @ClearOption(302)
     @ArDMA = "NONE"
     @ClearOption(303)
      @EndIf
      @If(@StrToInt(@SBPort) == -1)
     @SetOption(401)
     @ClearOption(304)
     @SBIRQ = "NONE"
     @ClearOption(305)
     @SBDMA = "NONE"
     @ClearOption(306)
      @ElseIf(@StrToInt(@SBIRQ) == -1)
     @ClearOption(305)
     @SBDMA = "NONE"
     @ClearOption(306)
      @EndIf
      @If(@StrToInt(@MiPort) == -1)
     @SetOption(402)
     @ClearOption(307)
     @MiIRQ = "NONE"
     @ClearOption(308)
      @EndIf
      @If(@StrToInt(@SiPort) == -1)
     @ClearOption(309)
      @EndIf
      @If(@StrToInt(@AdPort) == -1)
     @ClearOption(311)
      @EndIf
      @If(@StrToInt(@JoyPort) == -1)
     @JoyPort2 = "NONE"
     @ClearOption(312)
      @Else
     @JoyPort2 = "@JoySpeed"
      @EndIf
@EndIf

     @GetOption2(15,3,0,112)
    @FlushKeyboard
    @ClearOption(1)
    @ClearOption(2)
    @ClearOption(3)
    @ClearOption(4)
    @ClearOption(5)
    @ClearOption(6)
    @ClearOption(7)
    @ClearOption(8)
    @ClearOption(9)
    @ClearOption(10)
    @ClearOption(11)
    @ClearOption(12)
    @ClearOption(13)
    @ClearOption(14)
    @ClearOption(15)
    @ClearOption(16)
    @LocalWindow(10,35)                              @If(!(300 [= @Option))
    @Option 15 = "Store settings/Continue"
    @Option 14 = "Verify Settings/Play Tests"        @Else
    @Option 16 = "Return to main menu"
    @Option 15 = "Store as disabled/Exit"            @EndIf
    @If(301 [= @Option)
    @Option 1 = "Aria I/O Port (290)       : @Arport  *"
    @Else
    @Option 1 = "Aria I/O Port (290)       : @Arport   "
    @EndIf                                           @If(!(300 [= @Option))
    @If(302 [= @Option)
    @Option 2 = "Aria IRQ (10)             : @ArIrq   *"
    @Else
    @Option 2 = "Aria IRQ (10)             : @ArIrq    "
    @EndIf
    @If(303 [= @Option)
    @Option 3 = "Aria DMA (5)              : @ArDma    *"
    @Else
    @Option 3 = "Aria DMA (5)              : @ArDma    "
    @EndIf                                           @EndIf
    @If(304 [= @Option)
    @Option 4 = "SB Emul I/O Port(220)     : @SBPort  *"
    @Else
    @Option 4 = "SB Emul I/O Port(220)     : @SBPort   "
    @EndIf                                           @If(!(300 [= @Option))
    @If(305 [= @Option)
    @Option 5 = "SB Emul IRQ(7)            : @SBIrq    *"
    @Else
    @Option 5 = "SB Emul IRQ(7)            : @SBIrq    "
    @EndIf
    @If(306 [= @Option)
    @Option 6 = "SB Emul DMA(1)            : @SBDma    *"
    @Else
    @Option 6 = "SB Emul DMA(1)            : @SBDma     "
    @EndIf                                           @EndIf
    @If(307 [= @Option)
    @Option 7 = "MIDI I/O Port(330)        : @MiPort  *"
    @Else
    @Option 7 = "MIDI I/O Port(330)        : @MiPort  "
    @EndIf                                           @If(!(300 [= @Option))
    @If(308 [= @Option)
    @Option 8 = "MIDI IRQ(2/9)             : @MiIrq    *"
    @Else
    @Option 8 = "MIDI IRQ(2/9)             : @MiIrq    "
    @EndIf                                          @EndIf
    @If(311 [= @Option)
    @Option 11 ="ADLIB I/O Port(388)       : @AdPort  *"
    @Else
    @Option 11 ="ADLIB I/O Port(388)       : @AdPort   "
    @EndIf
    @If(312 [= @Option)
    @Option 12 ="Joystick I/O Port(NORMAL) : @JoyPort2  *"
    @Else
    @Option 12 ="Joystick I/O Port(NORMAL) : @JoyPort2   "
    @EndIf
    @Cls
@If(!(300 [= @Option)) @If(@ModifyMode == 1) @MoveCStr(1,21,31,"CURRENT SOUND CARD SETTINGS") @Else @MoveCStr(1,19,31,"SUGGESTED SOUND CARD SETTINGS")@EndIf















 Default values are in parentheses.  Highlight a parameter and hit <Enter> to
 view alternate settings. "NONE" indicates that a parameter is disabled.  An
 asterisk (*) indicates that a setting is unavailable.


                 @Else  @MoveCStr(1,22,31,"THE SOUND CARD IS DISABLED")













     The Aria I/O Port is set to "NONE".  Your sound card is disabled.
     You must set the Aria I/O Port to a valid value to enable the board.
     Highlight "Aria I/O Port (290) :NONE" and hit <Enter> to view
     alternate port settings.  You must enable the sound card before
     configuring any other parameters. @EndIf @EndOption
@If (1 [= @Option)  //Modify Parameter Options
    @ClearOption(301)
    @Parameter = 0
    @SetStr = "@ArIOSet"
@ElseIf (2 [= @Option)
    @ClearOption(302)
    @Parameter = 1
    @SetStr = "@ArIRQSet"
@ElseIf (3 [= @Option)
    @ClearOption(303)
    @Parameter = 2
    @SetStr = "@ArDMASet"
@ElseIf (4 [= @Option)
@If (300 [= @Option) @SetCursor(2) @GoTo ModifyParameters @EndIf
    @ClearOption(304)
    @Parameter = 3
    @SetStr = "@SBIOSet"
@ElseIf (5 [= @Option)
    @If(401 [= @Option)
       @Display
            SOUND BLASTER I/O PORT DISABLED



    You must set the Sound Blaster I/O Port (SB Emul I/O Port) to
    a valid address value before configuring either the Sound Blaster
    IRQ or DMA channel.


       @Pause
       @EndDisplay
       @SetCursor(6)
       @GoTo ModifyParameters
    @EndIf
    @ClearOption(305)
    @Parameter = 4
    @SetStr = "@SBIRQSet"
@ElseIf (6 [= @Option)
    @If(401 [= @Option)
       @Display
            SOUND BLASTER I/O PORT DISABLED



    You must set the Sound Blaster I/O Port (SB Emul I/O Port) to
    a valid address value before configuring either the Sound Blaster
    IRQ or DMA channel.


       @Pause
       @EndDisplay
       @SetCursor(7)
       @GoTo ModifyParameters
    @EndIf
    @ClearOption(306)
    @Parameter = 5
    @SetStr = "@SBDMASet"
@ElseIf (7 [= @Option)
@If (300 [= @Option) @SetCursor(2) @GoTo ModifyParameters @EndIf
    @ClearOption(307)
    @Parameter = 6
    @SetStr = "@MiIOSet"
@ElseIf (8 [= @Option)
    @If(402 [= @Option)
       @Display
                 MIDI I/O PORT DISABLED



    You must set the MIDI I/O Port to a valid address value before
    configuring the MIDI IRQ.


       @Pause
       @EndDisplay
       @SetCursor(9)
       @GoTo ModifyParameters
    @EndIf


    @ClearOption(308)
    @Parameter = 7
    @SetStr = "@MiIRQSet"
@ElseIf (9 [= @Option)
@If (300 [= @Option) @SetCursor(2) @GoTo ModifyParameters @EndIf
    @ClearOption(309)
    @Parameter = 8
    @SetStr = "@SiIOSet"
@ElseIf (11 [= @Option)
@If (300 [= @Option) @SetCursor(2) @GoTo ModifyParameters @EndIf
    @ClearOption(311)
    @Parameter = 10
    @SetStr = "@AdIOSet"
@ElseIf (12 [= @Option)
@If (300 [= @Option) @SetCursor(2) @GoTo ModifyParameters @EndIf
    @ClearOption(312)
    @Parameter = 11
    @SetStr = "@JoyIOSet"
@ElseIf (13 [= @Option)
    @ClearOption(313)
    @Parameter = 12
    @SetStr = "@JoySpeedSet"
@ElseIf(15 [= @Option)
    @GoTO SaveConfiguration
@ElseIf(16 [= @Option)
    @GoTo MainMenu
@ElseIf (14 [= @Option)   //Modify Parameters Option 12
    @ChDir("..")
    @GoTo VERIFY_PARAMETERS
@EndIf // ***** ModifyParameters Options


// ***** show available settings for each parameter
// ***** use asterisk to identify setting that is not available
ShowAlternateSettings:

@Setting1 = @StrToken(@SetStr,0,",")
@Setting2 = @StrToken(@SetStr,1,",")
@Setting3 = @StrToken(@SetStr,2,",")
@Setting4 = @StrToken(@SetStr,3,",")
@Setting5 = @StrToken(@SetStr,4,",")

@GetOption
@FlushKeyboard
@ClearOption(1)
@ClearOption(2)
@ClearOption(3)
@ClearOption(4)
@ClearOption(5)
@LocalWindow(6,35)
    @Option 1 = "@Setting1"
    @Option 2 = "@Setting2"
   @Endif
   @If((@StrToInt(@Setting3) > -1) || (@StrIndex(@Setting3,0) == 'N'))
    @Option 3 = "@Setting3"
   @Endif
   @If((@StrToInt(@Setting4) > -1) || (@StrIndex(@Setting4,0) == 'N'))
    @Option 4 = "@Setting4"
   @Endif
   @If((@StrToInt(@Setting5) > -1) || (@StrIndex(@Setting5,0) == 'N'))
    @Option 5 = "@Setting5"
   @Endif

   @Cls
     Select an alternate setting:








     An asterisk following a parameter indicates that the PC diagnostic
     utility has determined that the parameter is not available.  You
     may still select this value, but this may cause a conflict with
     another device in your system.

     Choose "NONE" to disable a parameter.  Selecting "NONE" for a port
     address setting disables the related IRQ and DMA settings.

     If you select a value that was previously assigned to a different
     parameter, the other parameter will be assigned a new value. Note
     that when you return to the Parameter screen, other parameter values
     in addition to the one just modified may have different values.
@EndOption

@If (1 [= @Option)
    @TempStr = "@Setting1"
@ElseIf (2 [= @Option)
    @TempStr = "@Setting2"
@ElseIf (3 [= @Option)
    @TempStr = "@Setting3"
@ElseIf (4 [= @Option)
    @TempStr = "@Setting4"
@ElseIf (5 [= @Option)
    @TempStr = "@Setting5"
@EndIf

@Flag1 = @StrFind(@TempStr,"*")
@If ( @Flag1 > -1)
    @TempStr = @StrHead(@TempStr,@Flag1)
    @SetOption(399)
@EndIf

@Flag2 = (@StrIndex(@TempStr,2) == 'N')
AssignValue:

@If (@Parameter == 0)
    @If((!(@StrIndex(@ArPort,1) == @StrIndex(@TempStr,1))) && (!@Flag2)  && (C [= @Group))
       @SetGroup(U)
    @EndIf
    @ArPort = "@TempStr"
    @If(399 [= @Option)@SetOption(301)@EndIf
    @SetCursor(2)
@ElseIf (@Parameter == 1)
    @If((!(@StrIndex(@ArIRQ,1) == @StrIndex(@TempStr,1))) && (!@Flag2)  && (C [= @Group))
       @SetGroup(U)
    @EndIf
    @ArIRQ = "@TempStr"
    @If(399 [= @Option)@SetOption(302)@EndIf
    @SetCursor(3)
@ElseIf (@Parameter == 2)
    @ArDMA = "@TempStr"
    @If(399 [= @Option)@SetOption(303)@EndIf
    @SetCursor(4)
@ElseIf (@Parameter == 3)
    @SBPort = "@TempStr"
    @If(399 [= @Option)@SetOption(304)@EndIf
    @SetCursor(5)
@ElseIf (@Parameter == 4)
    @SBIRQ = "@TempStr"
    @If(399 [= @Option)@SetOption(305)@EndIf
    @If((@StrFind(@SBIRQ,@MiIRQ) > -1) && (!(@StrToInt(@SBIRQ) == -1)))
        @MiIRQ = @NextAvailSetting(@MiIRQSet,@SBIRQ)
        @If(!(@StrToInt(@SBIRQ) == -1)) @SetGroup(U)
    @EndIf

        @Display
             MIDI IRQ CHANGED TO: @MiIRQ

    The Sound Blaster IRQ you selected is the same as the current MIDI
    IRQ.  CONFIG will change the current MIDI IRQ, setting it to the
    next available value (shown above).  If there is no available IRQ
    setting, the MIDI IRQ will be disabled (set to "NONE"); and you
    will not be able to use the MIDI interface of your sound card.

    On the following screen, you will have the opportunity to select
    alternate values for the MIDI IRQ.  Remember that you may force
    MIDI IRQ to a setting that is marked by an asterisk as unavailable.
    Note that this may result in a conflict with another device, and
    your system could hang.
        @Pause
        @EndDisplay
    @EndIf
    @SetCursor(6)
@ElseIf (@Parameter == 5)
    @SBDMA = "@TempStr"
    @If(399 [= @Option)@SetOption(306)@EndIf
    @SetCursor(7)
@ElseIf (@Parameter == 6)
    @If((!(@StrIndex(@MiPort,1) == @StrIndex(@TempStr,1))) && (!@Flag2)  && (C [= @Group))
       @SetGroup(U)
    @EndIf
    @MiPort = "@TempStr"
    @If(399 [= @Option)@SetOption(307)@EndIf
    @SetCursor(8)
@ElseIf (@Parameter == 7)
    @If((!(@StrIndex(@MiIRQ,0) == @StrIndex(@TempStr,0))) && (!@Flag2) && (C [= @Group))
       @SetGroup(U)
    @EndIf
    @MiIRQ = "@TempStr"
    @If(399 [= @Option)@SetOption(308)@EndIf
    @If ((@StrFind(@MiIRQ,@SBIRQ) > -1) && (!(@StrToInt(@MiIRQ) == -1)))
        @SBIRQ = @NextAvailSetting(@SBIRQSet,@MiIRQ)
        @Display
            SOUND BLASTER IRQ CHANGED TO: @SBIRQ

    The MIDI IRQ you selected is the same as the current Sound Blaster
    IRQ.  CONFIG will change the current Sound Blaster IRQ, setting it
    to the next available value (shown above).  If there is no available
    IRQ setting, the Sound Blaster IRQ will be disabled (set to "NONE");
    and you will not be able to use the Sound Blaster emulation feature
    of your sound card.

    On the following screen, you will have the opportunity to select
    alternate values for the Sound Blaster IRQ (SB Emul IRQ).  Remember
    that you may force the Sound Blaster IRQ to a setting that is marked
    by an asterisk as unavailable.  Note that this may result in a
    conflict with another device, and your system could hang.
        @Pause
        @EndDisplay
    @EndIf
    @SetCursor(9)
@ElseIf (@Parameter == 10)
    @AdPort = "@TempStr"
    @If(399 [= @Option)@SetOption(311)@EndIf
    @SetCursor(10)
@ElseIf (@Parameter == 11)
    @If (@StrFind(@TempStr,"NORM") > -1)
       @JoyPort = "200"
       @JoySpeed = "NORMAL"
    @ElseIf (@StrFind(@TempStr,"FAST") > -1)
       @JoyPort = "200"
       @JoySpeed = "FAST"
    @ElseIf (@StrFind(@TempStr,"NONE") > -1)
       @JoyPort = "NONE"
       @JoySpeed = "NORMAL"
    @EndIf
    @If(399 [= @Option)@SetOption(312)@EndIf
    @SetCursor(11)
@ElseIf (@Parameter == 12)
    @JoySpeed = "@TempStr"
    @If(399 [= @Option)@SetOption(313)@EndIf
    @SetCursor(12)
@EndIf
@ClearOption(399)
@GoTo ModifyParameters



VERIFY_PARAMETERS:

@Write("aria.cfg","wt","ARIA_BASE=@ArPort\n")
@Write("aria.cfg","at","ARIA_IRQ=@ArIRQ\n")
@Write("aria.cfg","at","ARIA_DMA=@ArDMA\n")
@Write("aria.cfg","at","SB_BASE=@SBPort\n")
@Write("aria.cfg","at","SB_IRQ=@SBIRQ\n")
@Write("aria.cfg","at","SB_DMA=@SBDMA\n")
@Write("aria.cfg","at","MIDI_BASE=@MiPort\n")
@Write("aria.cfg","at","MIDI_IRQ=@MiIRQ\n")
@Write("aria.cfg","at","CD-ROM=NONE\n")
@Write("aria.cfg","at","SCSI_IRQ=NONE\n")
@Write("aria.cfg","at","ADLIB_BASE=@AdPort\n")
@Write("aria.cfg","at","JOYSTICK_BASE=@JoyPort\n")
@Write("aria.cfg","at","JOYSTICK_SPEED=@JoySpeed\n")
@Write("aria.cfg","at","ROM_SIZE=512\n")
@Spawn("BIN\\boardcfg /Se 0 aria.cfg")

CHECKARIABOARD:

@If (!(@Spawn("BIN\\findaria.com") > 0))
   @Display
      @FlushKeyboard
        ARIA BOARD NOT DETECTED IN YOUR COMPUTER SYSTEM



     The Aria sound card must be physically installed in your PC
     before running this configuration program.  Press any key to exit to
     the DOS prompt, turn off your system, place the sound card in your
     computer, and re-run this program.

     If the sound card is installed, re-boot your system by turning your
     computer off and on; and re-run the coniguration program.  Simply
     hitting Ctr-Alt-Delete or RESET will not re-initialize the sound board.

      @PauseX
   @EndDisplay
   @Exit
@EndIf

@ChDir("BIN")
@ArPortHex = @HexToDec("@ArPort")
@SBPortHex = @HexToDec("@SBPort")
@MiPortHex = @HexToDec("@MiPort")

@If (Q [= @Group)   //QUICK_VERIFY
   @Display
            EXECUTING SOUND BOARD VERIFICATION PROGRAM


     If you experience any problems while running this verification utility,
     type "config" from the ARIA directory on your hard drive.  Select
     "Change hardware settings", and choose "Run the diagnostic utility".
     From the CURRENT SETTINGS Menu, do not run the verification procedure
     after choosing your hardware settings.  Select "Store settings..."
     to continue with the configuration program.


     Verifying @If(@Spawn("testaria 5 @ArPortHex") == 0)..@ClearOption(301)@ELSE@SetOption(301)@EndIf@If(301 [= @Option)@Else@If(@Spawn("testaria 6 @ArPortHex @ArIrq") == 0)..@ClearOption(302)@ELSE@SetOption(302)@EndIf@EndIf@If(301 [= @Option
     )@Else@If(@Spawn("testaria 7 @ArPortHex @ArIrq @ArDma") == 0)..@ClearOption(303)@ELSE@SetOption(303)@EndIf@EndIf@If(@Spawn("testaria 8 @SBPortHex") == 0)..@ClearOption(304)@ELSE@SetOption(304)@EndIf@If(304 [= @Option
     )@Else@If(@Spawn("testaria 9 @SBPortHex @SBIrq") == 0)..@ClearOption(305)@ELSE@SetOption(305)@EndIf@EndIf@If(304 [=@Option)@Else@If(@Spawn("testaria 10 @SBPortHex @SBIrq @SBDma")==0)..@ClearOption(306)@ELSE@SetOption(306)@EndIf@EndIf@If(
     @Spawn("testaria 11 @MiPortHex") == 0)..@ClearOption(307)@ELSE@SetOption(307)@EndIf@If(307 [= @Option)@Else@If(@Spawn("testaria 12 @MiPortHex @MiIrq") == 0)..@ClearOption(308)@ELSE@SetOption(308)@EndIf@EndIf

   @Pause
   @EndDisplay
@Else   // CUSTOM VERIFY
   @Display
            VERIFYING SOUND CARD SETTINGS
      @If(@StrFind(@ArPort,"NONE") > -1)
     @SetOption(301)

 Aria I/O Port: NONE   The sound card is disabled.

 You must set the Aria I/O Port to a valid value to enable the card.
 You will not be able to configure any sound board parameters until the
 sound board is enabled.

      @Else
 Verifying Aria I/O PORT :@ArPort @If(@Spawn("testaria 5 @ArPortHex") == 0)@MoveCStr(3,32,31,"FOUND")@ClearOption(301)@ELSE@MoveCstr(3,32,30,"NOT FOUND")@SetOption(301)@EndIf
 Verifying Aria IRQ      :@ArIRQ @If(301 [= @Option)@MoveCStr(4,32,30,"NOT TESTED")@Else@If(@Spawn("testaria 6 @ArPortHex @ArIrq") == 0)@movecstr(4,32,31,"FOUND")@ClearOption(302)@ELSE@MoveCStr(4,32,30,"NOT FOUND")@SetOption(302)@EndIf@EndIf
 Verifying Aria DMA      :@ArDMA @If(301 [= @Option)@MoveCStr(5,32,30,"NOT TESTED")@Else@If(@Spawn("testaria 7 @ArPortHex @ArIrq @ArDma") == 0)@MoveCStr(5,32,31,"FOUND")@ClearOption(303)@ELSE@MoveCStr(5,32,30,"NOT FOUND")@SetOption(303)@EndIf@EndIf
 Verifying Synthesizer Playback................. @If(301 [= @Option)@MoveCStr(6,51,30,"NOT TESTED")@Else@If(@Spawn("testaria 4 @ArPortHex") == 0)@MoveCStr(6,51,31,"TEST PASSED")@Else@MoveCStr(6,51,30,"TEST FAILED")@EndIf@EndIf
 Verifying Digital Audio Playback............... @If(301 [= @Option)@MoveCStr(7,51,30,"NOT TESTED")@Else@If(@Spawn("testaria 3 @ArPortHex @ArIRQ @ArDMA") == 0)@MoveCStr(7,51,31,"TEST PASSED")@Else@MoveCStr(7,51,30,"TEST FAILED")@EndIf@EndIf
       @If (@StrFind(@SBPort,"NONE") > -1)
 SB I/O Port  : NONE   Sound Blaster emulation is disabled
 SB IRQ       : NONE   SB I/O Port must be enabled before setting SB IRQ
 SB DMA       : NONE   SB I/O Port must be enabled before setting SB DMA
 Sound Blaster emulation playback not tested @Else
 Verifying SB I/O PORT   :@SBPort @If(@Spawn("testaria 8 @SBPortHex") == 0)@movecstr(9,32,31,"FOUND")@ClearOption(304)@ELSE@movecstr(9,32,30,"NOT FOUND")@SetOption(304)@EndIf
 Verifying SB IRQ        :@SBIRQ @If(304 [= @Option)@MovecStr(10,32,30,"NOT TESTED")@Else@If(@Spawn("testaria 9 @SBPortHex @SBIrq") == 0)@movecstr(10,32,31,"FOUND")@ClearOption(305)@ELSE@movecstr(10,32,30,"NOT FOUND")@SetOption(305)@EndIf@EndIf
 Verifying SB DMA        :@SBDMA @If(304 [= @Option)@MovecStr(11,32,30,"NOT TESTED")@Else@If(@Spawn("testaria 10 @SBPortHex @SBIrq @SBDma") == 0)@movecstr(11,32,31,"FOUND")@ClearOption(306)@ELSE@movecstr(11,32,30,"NOT FOUND")@SetOption(306)@EndIf@EndIf
 Verifying Sound Blaster emulation playback..... @If(304 [= @Option)@MovecStr(12,51,30,"NOT TESTED")@Else @If(@Spawn("testaria 2 @SBPortHex") == 0)@MoveCStr(12,51,31,"TEST PASSED")@Else@MoveCStr(12,51,30,"TEST FAILED")@EndIf@EndIf@EndIf
      @If (@StrFind(@MiPort,"NONE") > -1)
 MIDI I/O PORT: NONE   MIDI interface is disabled
 MIDI IRQ     : NONE   MIDI I/O Port must be enabled before setting MIDI IRQ @Else@If(J [= @Group)
 Verifying MIDI I/O PORT :@MiPort   @If(@Spawn("testaria 11 @MiPortHex") != 0)@moveCStr(14,1,30,"The MIDI PORT and IRQ can not be verified until you change the   ")@moveCStr(15,1,30,"jumpers/switches on your CD-ROM card, re-boot, and re-run CONFIG")
 @Else@If(@Spawn("testaria 11 @MiPortHex") == 0)@movecstr(14,32,31,"FOUND")@ClearOption(307)@ELSE@If(!(J [= @Group))@moveCStr(14,32,30,"NOT FOUND")@Else@moveCStr(14,32,30,"NOT TESTED")@EndIf@SetOption(307)@EndIf
 Verifying MIDI IRQ      :@MiIRQ     @If(307 [= @Option)@MovecStr(15,32,30,"NOT TESTED")@Else@If(@Spawn("testaria 12 @MiPortHex @MiIrq") == 0)@movecstr(15,32,31,"FOUND")@ClearOption(308)@ELSE@movecstr(15,32,30,"NOT FOUND")@SetOption(308)@EndIf@EndIf
 @EndIf@Else
 Verifying MIDI I/O PORT :@MiPort  @If(@Spawn("testaria 11 @MiPortHex") == 0)@movecstr(14,32,31,"FOUND")@ClearOption(307)@ELSE@If(!(J [= @Group))@moveCStr(14,32,30,"NOT FOUND")@Else@moveCStr(14,32,30,"NOT TESTED")@EndIf@SetOption(307)@EndIf
 Verifying MIDI IRQ      :@MiIRQ   @If(307 [= @Option)@MovecStr(15,32,30,"NOT TESTED")@Else@If(@Spawn("testaria 12 @MiPortHex @MiIrq") == 0)@movecstr(15,32,31,"FOUND")@ClearOption(308)@ELSE@movecstr(15,32,30,"NOT FOUND")@SetOption(308)@EndIf@EndIf
 @EndIf@EndIf@EndIf
 @Pause
   @EndDisplay
@EndIf

TEST_RESULTS:
@If((301 [= @Option) || (302 [= @Option) || (303 [= @Option) ||
    (304 [= @Option) || (305 [= @Option) || (306 [= @Option) ||
    (307 [= @Option) || (308 [= @Option))  //Test Failed
     @If(Q [= @Group)
    @ClearGroup(Q)
    @SetGroup(C)
    @SetGroup(V)
     @EndIf
     @GoTo ModifyParameters
@EndIf

TestPassed:

@GetOption
@ClearOption(1)
@ClearOption(2)
    @Option 1 = "Save configuration"
    @Option 2 = "Change settings"

@LocalWindow(18,33)
@Cls
            VERIFICATION TEST PASSED

     CONFIG has verified the following sound card settings:

               Aria I/O Port       :@ArPort
               Aria IRQ            :@ArIRQ
               Aria DMA            :@ArDMA
               SB Emulation Port   :@SBPort
               SB Emulation IRQ    :@SBIRQ
               SB Emulation DMA    :@SBDMA
               MIDI Port           :@MiPort
               MIDI IRQ            :@MiIRQ
               Adlib Port          :@AdPort
               Joystick (Speed)    :@JoyPort2




 @EndOption
@If(2 [= @Option)
     @FlushOptions()
     @If(Q [= @Group)
    @ClearGroup(Q)
    @SetGroup(C)
    @SetGroup(V)
     @EndIf
     @GoTo ModifyParameters
@EndIf
SaveConfiguration:

      @ChDir("..")
      @Write("aria.cfg","wt","ARIA_BASE=@ArPort\n")
      @Write("aria.cfg","at","ARIA_IRQ=@ArIRQ\n")
      @Write("aria.cfg","at","ARIA_DMA=@ArDMA\n")
      @Write("aria.cfg","at","SB_BASE=@SBPort\n")
      @Write("aria.cfg","at","SB_IRQ=@SBIRQ\n")
      @Write("aria.cfg","at","SB_DMA=@SBDMA\n")
      @Write("aria.cfg","at","MIDI_BASE=@MiPort\n")
      @Write("aria.cfg","at","MIDI_IRQ=@MiIRQ\n")
      @Write("aria.cfg","at","CD-ROM=NONE\n")
      @Write("aria.cfg","at","SCSI_IRQ=NONE\n")
      @Write("aria.cfg","at","ADLIB_BASE=@AdPort\n")
      @Write("aria.cfg","at","JOYSTICK_BASE=@JoyPort\n")
      @Write("aria.cfg","at","JOYSTICK_SPEED=@JoySpeed\n")
      @Write("cfg.001","wt","&!+   %# @@@@")
      @Write("aria.cfg","at","ROM_SIZE=512\n")
      @Rsize = "R1"
      @If(@StrIndex(@ArPort,0) == 'N') @Setting4 ="NON" @Else @Setting4 = "@ArPort" @EndIf
      @If(@StrIndex(@ArIRQ,0) == 'N') @Setting5 ="NO" @Else @Setting5 = "@ArIRQ" @EndIf
      @If(@StrIndex(@MiPort,0) == 'N') @Setting2 ="NON" @Else @Setting2 = "@MiPort" @EndIf
      @If(@StrIndex(@MiIRQ,0) == 'N') @Setting3 ="N" @Else @Setting3 = "@MiIRQ" @EndIf
      @Write("WIN\\temp.txt","wt","A@Setting4 I@Setting5 M@Setting2 Q@Setting3 @Rsize S1")
      @Spawn("BIN\\boardcfg /Se 0 aria.cfg")
      @If (300 [= @Option)
     @FlushOptions()
     @EXIT
      @EndIf
ModifyAutoexec:
@GetOption
@ClearOption(1)
@ClearOption(2)
@LocalWindow(17,35)
@Cls
              MODIFY AUTOEXEC.BAT & CONFIG.SYS

     The following lines should be added to your AUTOEXEC.BAT file:

    SET ARIA=A@ArPort I@ArIRQ D@ArDMA @AriaConf
    SET BLASTER=A@SBPort I@SBIRQ D@SBDMA @AriaConf

     The following line should be added to your CONFIG.SYS file:

    DEVICE=@AriaDir\BIN\SOUNDCFG.SYS @AriaDir\aria.cfg

     Choose "Modify" to automatically make these changes.

 @Option 1 = "Modify"
 @Option 2 = "Do not modify"
@EndOption
@If (1 [= @Option)
   @ChDrive(C)
   @ChDir("\\")
   @If (!@Exists("autoexec.bat"))
      @Display

    AUTOEXEC.BAT not found on drive C

    Consult the Aria Sound Card User's Guide about manually
    modifying your AUTOEXEC.BAT file.

      @Pause
      @EndDisplay
   @Else
      @AddFileStr("autoexec.bat","SET ARIA=A@ArPort I@ArIRQ D@ArDMA @AriaConf","SET ARIA=",0,"SET ARIA=",)
      @AddFileStr("autoexec.bat","SET BLASTER=A@SBPort I@SBIRQ D@SBDMA @AriaConf","SET BLASTER=",1,"SET BLASTER=",)
   @EndIf
   @If (!@Exists("config.sys"))
      @Display

    CONFIG.SYS not found on drive C

      @Pause
      @EndDisplay
   @Else
      @AddFileStr("config.sys","DEVICE=@AriaDir\\BIN\\soundcfg.sys @AriaDir\\aria.cfg","\\BIN\\soundcfg",0,"aria.cfg",)
   @EndIf
      @ChangeDir(@AriaDir)
@EndIf
@Flag1 = 0

@If(V [= @Group)   // resume quick install
  @ClearGroup(V)
  @ClearGroup(C)
  @SetGroup(Q)
@EndIf

UPDATE_WIN_DRIV:
@If (C [= @Group)
   @If (@Exists("wincfg.tmp"))
     @WinDir = @ReadLine("wincfg.tmp",0,"=")
   @Else
     @WinDir = "C:\\WINDOWS"
   @EndIf
   @If( (@StrFind(@ArPort,"NONE") > -1) ||
      (!(U [= @Group)) || !@Exists("@WinDir\\SYSTEM\\aria.drv"))
      @ClearGroup(U)
      @GoTo CUSTOM_MENU
   @EndIf
   @ClearGroup(U)
   @If(!(F [= @Group))  // not first-time custom install
      @GetOption
     @ClearOption(1)
     @ClearOption(2)
     @LocalWindow(13,38)
     @Cls
             UPDATE THE ARIA WINDOWS DRIVER



     When you change your Aria I/O Port, Aria IRQ, MIDI I/O Port, or MIDI
     IRQ setting, you must update the Aria Windows driver with the
     changed values.  CONFIG will automatically add the new settings to
     your Windows SYSTEM.INI file.

     @Option 1 = "Update Windows driver"
     @Option 2 = "Return to main menu"
      @EndOption
      @If (2 [= @Option)
     @GoTo CUSTOM_MENU
      @EndIf

      @If (@Exists("wincfg.tmp"))
     @WinDir = @ReadLine("wincfg.tmp",0,"=")
      @Else
     @WinDir = "C:\\WINDOWS"
      @EndIf

GetWinChk:

      @If(@Exists("@WinDir\\system\\aria.drv"))
     @Write("wincfg.tmp","wt","win=@WinDir\n")
     @ChangeDir(@WinDir)
     @If(@BatStrExists("system.ini","[aria.drv]"))
        @ReplaceFileStr("system.ini","dspport=","dspport=0x@ArPort",1)
        @ReplaceFileStr("system.ini","dspirq=","dspirq=@ArIRQ",1)
        @ReplaceFileStr("system.ini","midiport=","midiport=0x@MiPort",1)
        @ReplaceFileStr("system.ini","midiirq=","midiirq=@MiIRQ",1)
        @ChangeDir(@AriaDir)
        @ChDir("\\")
        @ChDir("@AriaDir")
        @Flag1 = 0
        @ClearGroup(U)
        @Goto Custom_Menu
     @Endif
      @Endif
GET_WIN_DIR:
      @FlushKeyboard

      @GetString @WinDir
      @LocalWindow(15,29)
      @Prompt = "Windows directory"
      @Cls
            WINDOWS DRIVER CONFIGURATION NOT FOUND


     CONFIG does not detect a configured Aria Windows driver in the
     directory listed below.  Press the <ESC> key to erase the displayed
     text, and type in the full path name to the Windows directory where the
     Aria driver is installed.  When specifying the full path, type
     in the drive letter and directory name.  For example: C:\WINDOWS.

     If you have not installed the Aria Windows driver or want to
     return to the main menu, type 'NONE'.

      @EndString
      @If((@StrIndex(@WinDir,0) == 'n') ||
     (@StrIndex(@WinDir,0) == 'N'))
     @WinDir = "C:\\Windows"
     @GoTo CUSTOM_MENU
      @EndIf
      @GoTo GetWinChk
   @Else  // Initial Custom installation
      @GetOption
     @ClearOption(1)
     @ClearOption(2)
     @LocalWindow(13,39)
     @Cls
               SET UP THE ARIA WINDOWS DRIVER



     The Aria Windows driver is not currently installed.  Do you
     want to set up the Aria Windows driver with the current sound
     card settings?


     @Option 1 = "Set up the Aria Windows driver"
     @Option 2 = "Return to main menu"
     @EndOption
     @If(2 [= @Option)
    @GoTo Custom_Menu
     @EndIf
    @SetGroup(W)
  @EndIf
   @GoTo CUSTOM_MENU
@EndIf  // Set up Windows driver


SetupWin:
Setwinconf:
@If (W [= @Group)
   @If(C [= @Group)
      @If(!@Exists("aria.cfg"))
     @Display
            HARDWARE CONFIGURATION FILE NOT FOUND




     You must set up your hardware before setting up the Aria Windows driver.
     Press any key to return to the main menu.  From the main menu, select
     "Change hardware settings" and configure your sound card.
     @Pause
     @EndDisplay
     @GoTo CUSTOM_MENU
      @Else
     @ArPort = @ReadLine("aria.cfg",0,"=")
     @ArIRQ  = @ReadLine("aria.cfg",1,"=")
     @MiPort = @ReadLine("aria.cfg",6,"=")
     @MiIRQ  = @ReadLine("aria.cfg",7,"=")
     @Setting1 = "S1"
     @If(@StrIndex(@ArPort,0) == 'N') @Setting4 ="NON" @Else @Setting4 = "@ArPort" @EndIf
     @If(@StrIndex(@ArIRQ,0) == 'N') @Setting5 ="NO" @Else @Setting5 = "@ArIRQ" @EndIf
     @If(@StrIndex(@MiPort,0) == 'N') @Setting2 ="NON" @Else @Setting2 = "@MiPort" @EndIf
     @If(@StrIndex(@MiIRQ,0) == 'N') @Setting3 ="N" @Else @Setting3 = "@MiIRQ" @EndIf

     @Write("WIN\\temp.txt","wt","A@ArPort I@ArIrq M@Setting2 Q@Setting3 @Rsize @Setting1")
      @EndIf   // aria.cfg exists

      @If (@Exists("wincfg.tmp"))
        @WinDir = @ReadLine("wincfg.tmp",0,"=")
      @Else
        @WinDir = "C:\\WINDOWS"
      @EndIf
      @If (!@Exists("@WinDir\\win.com"))

GetWinDir3:
     @FlushKeyboard

     @GetString @WinDir
     @LocalWindow(13,29)
     @Prompt = "Windows directory"
     @Cls
               WINDOWS DIRECTORY NOT FOUND



     If the directory path appearing in the displayed box is not the correct
     path to your Windows directory, press the <ESC> key to erase this text.
     Type in the full path name.  When specifying the full path, type in the
     drive letter and directory name.  For example: C:\WINDOWS.

     Type "NONE" to skip this screen and return to the main menu.
    @EndString
     @If((@StrIndex(@WinDir,0) == 'n') ||
          (@StrIndex(@WinDir,0) == 'N'))
        @WinDir = "C:\\Windows"
        @GoTo CUSTOM_MENU
     @EndIf

     @If (!@Exists("@WinDir\\win.com"))
         @Flag1 = 1
         @GoTo GetWinDir3
     @EndIf
     @Write("wincfg.tmp","wt","win=@WinDir\n")
     @Flag1 = 0
     @EndIf  // Get Windows directory

     @FlushKeyboard
     @GetOption
     @ClearOption(1)
     @ClearOption(2)
     @ClearOption(3)
     @Option 1 =  "Install in Windows"
     @Option 2 =  "Return to main menu"
     @Option 3 =  "Exit to DOS"
     @LocalWindow(19,39)
     @Cls
               INSTALL ARIA WINDOWS DRIVER

     CONFIG will configure the driver with the following parameter values.
     Select "Return to main menu" to select alternate settings.

                 Aria I/O Port   :@ArPort
                 Aria IRQ        :@ArIRQ
                 MIDI I/O Port   :@MiPort
                 MIDI IRQ        :@MiIRQ

     NOTE.  Before running Aria with DOS applications, remember to re-boot
     your system to initialize DOS environment variables.  Re-boot by
     turning the power off and on.
     @EndOption
     @If (3 [= @Option)
        @Spawn("BIN\\boardcfg /Se 0 aria.cfg")
        @Exit
     @ElseIf (2 [= @Option)
        @GoTo CUSTOM_MENU
     @EndIf

   @ElseIf(Q [= @Group)

     @FlushKeyboard

     @GetOption
     @ClearOption(1)
     @ClearOption(2)
     @Option 1 = "Install in Windows"
     @Option 2 = "Exit to DOS"
     @LocalWindow(18,39)
     @Cls
               INSTALL ARIA WINDOWS DRIVER



     To set up the Aria Windows driver, the installation program
     must now launch Microsoft Windows.

     NOTE.  After the install program is done, remember to re-boot your
     computer before using Aria with DOS applications.  To re-boot, remove
     the installation disk from your floppy drive, and turn the PC power off
     and on.
     @EndOption
     @If (2 [= @Option)

           @Display
                RE-BOOT YOUR COMPUTER




     If you want to set up the Aria sound card in Windows at a later
     time, type "config" from the ARIA directory on your hard drive.  Choose
     "Set up Aria Windows driver".  Follow the instructions on the screens.

     After exiting the Aria sound card configuration program, you must
     re-boot your computer in order to initialize the DOS environment
     variables.  You should also re-boot if you change your sound card's
     hardware settings (I/O, IRQ, or DMA).

     To re-boot your computer, turn your system power off and on.

           @PauseX
           @EndDisplay
           @Exit
    @EndIf
   @EndIf //Quick Install and  Windows install confirmed

   @If (@Exists("@WinDir\\SYSTEM\\aria.drv"))  // delete current aria.drv set up
      @Flag1 = 0
      @ChangeDir(@WinDir)

      @If(@BatStrExists("system.ini","[aria.drv]"))
     @ReplaceFileStr("system.ini","Wave=aria.drv","Wave=")
     @ReplaceFileStr("system.ini","MIDI=aria.drv","MIDI=")
     @ReplaceFileStr("system.ini","AUX=aria.drv","AUX=")
     @DelFileBlk("system.ini","[aria.drv]","[")
      @EndIf
      @If(@BatStrExists("win.ini","[MixMaster]"))
     @DelFileBlk("win.ini","[MixMaster]","[")
      @EndIf
      @If(@BatStrExists("progman.ini","AriaMul"))
     @ReplaceFileStr("progman.ini","AriaMul","",1)
     @Delete("AriaMul*.GRP")
      @EndIf
   @EndIf
   @FlushOptions()
   @SetOption(909)
   @ChangeDir(@AriaDir)
   @ChDir("WIN")
@Else   //  not setting up Aria in Windows
    @If (C [= @Group)
    @GoTo CUSTOM_MENU
    @EndIf
    @Display
              EXITING THE ARIA CONFIGURATION PROGRAM

      You have chosen not to set up the Aria sound card software in Windows.
      To set up Aria in Windows at a later time, type "config" from the ARIA
      directory on your hard drive.  From the main menu, select "Set up Aria
      Windows driver" and follow the screen instructions.

      You must re-boot your PC to initialize the Aria DOS environment
      variables.  Re-boot by turning the computer power off and on.
    @PauseX
     @EndDisplay
     @EXIT
@EndIf // ***** Installing to Windows

Done:
@Finish
   @If (999 [= @Option)
      @Exit
   @ElseIf (909 [= @Option)
       @Write("..\\wincfg.tmp","wt","win=@WinDir\n")
       @Execute("@WinDir\\win setup.exe")
      @Move(2,3,"This program is unable to launch Windows.  Exit to DOS, and")
      @MOve(3,3,"go to the directory where you have installed the Aria files.")
      @Move(4,3,"From this directory type \"win setup\" to set up the Aria")
      @Move(5,3,"Windows driver.")

      @Move(8,3,"If you are still unable to launch Windows, make sure that")
      @Move(9,3,"the Windows directory is in your PATH statement. From any")
      @Move(10,3,"prompt type \"PATH,\" and look for the Windows directory (See")
      @Move(11,3,"your DOS manual for more information concerning PATH).")

      @MOve(13,3,"After confirming that the Windows directory is in your PATH,")
      @Move(14,3,"make sure that Windows is properly installed and operating")
      @Move(15,3,"correctly by typing \"win\" from any prompt. Consult the Windows")
      @Move(16,3,"manual if you are still having problems running Windows.")
      @Pause
      @EXIT
    @EndIf
@EndFinish